# Distributed under the terms of the GNU General Public License v2

EAPI=4


PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS=1
RESTRICT_PYTHON_ABIS="2.5 3.* *-jython *-pypy-*"

inherit eutils python

DESCRIPTION="Funtoo Core Boot Framework for global boot loader configuration"
HOMEPAGE="http://www.funtoo.org/en/funtoo/core/boot"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="*"
RESTRICT="mirror"
GITHUB_REPO="boot-update"
GITHUB_USER="funtoo"
GITHUB_TAG="${PV}"
SRC_URI="https://www.github.com/${GITHUB_USER}/${GITHUB_REPO}/tarball/${GITHUB_TAG} -> boot-update-${GITHUB_TAG}.tar.gz"

IUSE=""

DEPEND=""
RDEPEND=">=sys-boot/grub-2.00"


src_prepare() {
	epatch "${FILESDIR}/${PN}-1.6.11-grub2-gentoo.patch"
}


src_unpack() {
	unpack ${A}
	mv "${WORKDIR}/${GITHUB_USER}-${PN}"-??????? "${S}" || die
}

src_test() {
	testing() {
		PYTHONPATH="${S}/python/modules" "$(PYTHON)" FuntooSuite.py
	}
	cd tests || die
	python_execute_function testing
}




src_install() {
	dodoc doc/*.rst

	doman doc/boot-update.8
	doman doc/boot.conf.5

	into /
	dosbin sbin/boot-update

	dodoc etc/boot.conf.example
	insinto /etc
	doins etc/boot.conf
	doins etc/boot.conf.defaults
	doins etc/boot.conf.example


	installing() {
		insinto "$(python_get_sitedir)"
		doins -r funtoo
	}
	cd python/modules || die
	python_execute_function installing

}

src_compile() {
	return
}


pkg_postinst() {
	python_mod_optimize funtoo
}

pkg_postrm() {
	python_mod_cleanup funtoo
}